ecoff
rdoff
point 10001,10001;
golayer MacroConstruction
scriptm #roughpath-vars.scr
ifdef mcoVarsOK mcoDoneVarCheck
:mcoDefineVars
gv mcoLW 10
gv mcoLW ^DPath width? (10)
gv mcoPR 1
gv mcoPR ^DPath roughness? (.9=smoother, 1.1=rougher) (1)
gv mcoPC 1
gv mcoPC ^DPath complexity (.9=less nodes, 1.1=more nodes) (1)
gv mcoPC 1/mcoPC
savevars roughpath-vars
gw mcoVarsOK OK
go mcoStart
:mcoDoneVarCheck
gv mcoUseDefault 1
gv mcoUseDefault ^DUse saved settings? (1=yes - default - click) (0=no)
ifz mcoUseDefault mcoDefineVars
:mcoStart
ge mcoEntity ^DSelect object to convert:
iferr mcoDrawPath
gdist mcoDist % 0 mcoEntity % .1 mcoEntity
gv mcoUnit 100/(mcoDist*1000)
gp mcoP1 % 0 mcoEntity
gbrng mcoB12 mcoP1 % .01 mcoEntity
random mcoR1
random mcoR2
gp mcoP1a ref mcoP1 <mcoB12+90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR1-.5))
gp mcoP1b ref mcoP1 <mcoB12-90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR2-.5))
gv mcoStep mcoLW*mcoPC*mcoUnit
gv mcoStep2 mcoStep
:mcoSEGLOOP
gp mcoP3 % mcoStep mcoEntity
gp mcoP4 % mcoStep2 mcoEntity
ifp mcoStep-100 mcoDONESEGLOOP
ifp mcoStep2-100 mcoDONESEGLOOP
random mcoR1
random mcoR2
gbrng mcoB12 % mcoStep mcoEntity % mcoStep+.01 mcoEntity
gp mcoP3a ref mcoP3 <mcoB12+90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR1-.5))
gp mcoP3b ref mcoP4 <mcoB12-90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR2-.5))
poly mcoP1a mcoP1b mcoP3b mcoP3a;
gp mcoP1a mcoP3a
gp mcoP1b mcoP3b
random mcoR1
random mcoR2
gv mcoStep2 mcoStep+((mcoLW/2)+(mcoLW/2*mcoR2))*mcoPC*mcoUnit
gv mcoStep mcoStep+((mcoLW/2)+(mcoLW/2*mcoR1))*mcoPC*mcoUnit
go mcoSEGLOOP
:mcoDONESEGLOOP
gbrng mcoB12 % 99.9 mcoEntity % 100 mcoEntity
gp mcoP2 % 100 mcoEntity
poly mcoP1a mcoP1b ref mcoP2 <mcoB12-90,mcoLW/2 ref mcoP2 <mcoB12+90,mcoLW/2;
go mcoDone
:mcoDrawPath
gp mcoP1 ^DStart path...
iferr mcoDONE
line mcoP1 ^DNext point... (right click ends);
undo
gp mcoP2 @0,0
gdist mcoD12 mcoP1 mcoP2
ifz mcoD12 mcoDONE
lstyle solid;fstyle solid;lwidth 0
gbrng mcoB12 mcoP1 mcoP2
random mcoR1
random mcoR2
gp mcoP1a ref mcoP1 <mcoB12+90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR1-.5))
gp mcoP1b ref mcoP1 <mcoB12-90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR2-.5))
gv mcoStep mcoLW*mcoPC
gv mcoStep2 mcoStep
go mcoSEGLOOP2
:mcoLINELOOP
line mcoP1 ^DNext point... (right click ends);
undo
gp mcoP2 @0,0
gdist mcoD12 mcoP1 mcoP2
ifz mcoD12 mcoCLEANUP
gbrng mcoB12 mcoP1 mcoP2
gv mcoStep mcoLW*mcoPC
gv mcoStep2 mcoStep
:mcoSEGLOOP2
gp mcoP3 ref mcoP1 <mcoB12,mcoStep
gp mcoP4 ref mcoP1 <mcoB12,mcoStep2
gdist mcoD13 mcoP1 mcoP3
ifp mcoD13-mcoD12 mcoDONESEGLOOP2
gdist mcoD14 mcoP1 mcoP4
ifp mcoD14-mcoD12 mcoDONESEGLOOP2
random mcoR1
random mcoR2
gp mcoP3a ref mcoP3 <mcoB12+90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR1-.5))
gp mcoP3b ref mcoP4 <mcoB12-90,(mcoLW*.75)+(mcoLW*.25*mcoPR*(mcoR2-.5))
poly mcoP1a mcoP1b mcoP3b mcoP3a;
gp mcoP1a mcoP3a
gp mcoP1b mcoP3b
random mcoR1
random mcoR2
gv mcoStep2 mcoStep+((mcoLW/2)+(mcoLW/2*mcoR2))*mcoPC
gv mcoStep mcoStep+((mcoLW/2)+(mcoLW/2*mcoR1))*mcoPC
go mcoSEGLOOP2
:mcoDONESEGLOOP2
gp mcoP1 mcoP2
go mcoLINELOOP
:mcoCLEANUP
poly mcoP1a mcoP1b ref mcoP2 <mcoB12-90,mcoLW/2 ref mcoP2 <mcoB12+90,mcoLW/2;
:mcoDone
selbyl
changel MacroConstruction
like
10001,10001
selbyp
group
:mcoabort
selby1
keep 10001,10001
erase 10001,10001
selrest
rdon
econ